// Bricks
//
//This macro is designed to run as many brickracks as you want as long as they fit
//on the screen with Cartographer View (Double F8) zoomed all the way in.
//INSTRUCTIONS:
//  1) "Enable hotkeys on brickracks" under Utility>One click and related
//  2) Minimize all windows so you can see all of the racks
//  3) Have the needed supplies in your inventory
//  4) Put your pointer in the middle of the rack in top left corner
//  5) Alt tab to ACTool (Don't touch the mouse)
//  6) Press F2, Fill in the box.  Your settings will be saved
//
//Enjoy :)  Anka   /tell me if you have problems.
Constants
  Rounds = 0    //Number of times to run the macro
  RacksX = 0    //Set this to the number of brickracks you have across
  RacksY = 0    //Set this to the number of brickracks you have up and down
  StartX = 0
  StartY = 0
  NewX = 0
  NewY = 0
  TempX = 0
  TempY = 0
  CheckX = 21
  CheckY = 5
  AddX = 102
  AddY = 102
  Color = 0
  Color2 = 0
  ColorSet = 0
  Bricks = B
  MDelay = 200    //Mouse move delay, higher numer = slower
  SDelay = 200    //Another delay to play with if you need to slow or speed up
  Job = 0
End

SetConst StartX = {mousex}
SetConst StartY = {mousey}

Form Bricks, Choose your Job
  ed1=EditBox:Rounds:1
  ed2=Combobox:Which Job?:Bricks, FireBricks
  ed3=EditBox:Racks Across:1
  ed4=EditBox:Racks Down:1
end

FormLoad Bricks, Bricks.frm

if ShowForm Bricks
  Set Rounds = Bricks[ed1]
  Set Job = Bricks[ed2]
  Set RacksX = Bricks[ed3]
  Set RacksY = Bricks[ed4]
else
  Stop
end

FormSave Bricks, Bricks.frm

MousePos 100, 20
Delay $MDelay
LeftClick
Delay 2000

Loop $Rounds
  Call $Job
  Call Takebricks
End

Procedure Bricks
  SetConst Bricks = B
  Call Makebricks
End

Procedure FireBricks
  SetConst Bricks = F
  Call MakeBricks
End

Procedure MakeBricks
  SetConst NewX = $StartX
  SetConst NewY = $StartY
  
  Loop $RacksY
    Loop $RacksX
      MousePos $NewX, $NewY
      Delay $SDelay
      Keys $Bricks
      Delay $SDelay
      Compute NewX = $NewX + $AddX
    End
    Compute NewX = $StartX
    Compute NewY = $NewY + $AddY
  End
  Compute NewX = $StartX
  Compute NewY = $StartY
End

Procedure TakeBricks
  Compute NewX = $StartX - $CheckX
  Compute NewY = $StartY - $CheckY
  
  Loop $RacksY
    Loop $RacksX
      MousePos $NewX, $NewY
      Delay $SDelay
      Call CheckBricks
      Delay $SDelay
      Compute NewX = $NewX + $AddX
    End
    Compute NewX = $StartX - $CheckX
    Compute NewY = $NewY + $AddY
  End
  Compute NewX = $StartX
  Compute NewY = $StartY
  SetConst ColorSet = 0
End

Procedure CheckBricks
  Mousepos $NewX, $NewY
  loadrgb {mousex}, {mousey}
  If $ColorSet = 0
    SetConst Color = {rgbred}
    Compute Color2 = $Color + 16
    SetConst ColorSet = 1
  End
  
  While {rgbred} < $Color2
    Mousepos $NewX, $NewY
    loadrgb {mousex}, {mousey}
    If {rgbred} > $Color2
      Continue
    Else
      Compute TempY = $NewY - 1
      MousePos $NewX, $TempY
      loadrgb {mousex}, {mousey}
      If {rgbred} > $Color2
        Continue
      Else
        Compute TempY = $NewY + 1
        MousePos $NewX, $TempY
        loadrgb {mousex}, {mousey}
      End
    End
  End
  Keys T
End
Bell Asterisk
//Written by Anka with AC Tool 5.3.0